@file:Suppress("VulnerableLibrariesLocal")

plugins {
    id("java")
}

group = "cn.hamster3.mc.plugin"
version = "1.1.3"
description = "支持跨服传送的 tpa 插件"

repositories {
    maven {
        url = uri("https://maven.airgame.net/maven-public/")
    }
}

dependencies {
    // https://mvnrepository.com/artifact/org.jetbrains/annotations
    compileOnly("org.jetbrains:annotations:24.1.0")
    // https://mvnrepository.com/artifact/org.projectlombok/lombok
    compileOnly("org.projectlombok:lombok:1.18.30")
    annotationProcessor("org.projectlombok:lombok:1.18.30")

    compileOnly("org.spigotmc:spigot-api:1.18.2-R0.1-SNAPSHOT")

    compileOnly("cn.hamster3.mc.plugin:core-bukkit:1.2.2")
    compileOnly("cn.hamster3.mc.plugin:ball-bukkit:1.5.3")
}


tasks {
    withType<JavaCompile>().configureEach {
        options.encoding = "UTF-8"
    }
    withType<Jar>().configureEach {
        from(rootProject.file("LICENSE"))
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }
    java {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
        withSourcesJar()
    }
    jar {
        archiveBaseName = "HamsterTPA"
        destinationDirectory = rootProject.layout.buildDirectory
    }
    processResources {
        filesMatching("plugin.yml") {
            expand(project.properties)
        }
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }
}