@file:Suppress("VulnerableLibrariesLocal")

plugins {
    id("java")
    id("com.github.johnrengelman.shadow") version "8+"
}

group = "cn.hamster3.mc.plugin"
version = "1.0.5"
description = "为Minecraft服务器导入 OpenJDK Nashorn 引擎来执行 JavaScript 脚本"

repositories {
    maven {
        url = uri("https://maven.airgame.net/maven-public/")
    }
}

dependencies {
    // https://mvnrepository.com/artifact/org.jetbrains/annotations
    compileOnly("org.jetbrains:annotations:24.1.0")
    // https://mvnrepository.com/artifact/org.projectlombok/lombok
    compileOnly("org.projectlombok:lombok:1.18.30")
    annotationProcessor("org.projectlombok:lombok:1.18.30")

    compileOnly("org.spigotmc:spigot-api:1.18.2-R0.1-SNAPSHOT")

    // https://mvnrepository.com/artifact/org.openjdk.nashorn/nashorn-core
    implementation("org.openjdk.nashorn:nashorn-core:15.4")
}

tasks {
    java {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
        withSourcesJar()
    }
    processResources {
        filesMatching("plugin.yml") {
            expand(project.properties)
        }
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }
    jar {
        destinationDirectory = rootProject.layout.buildDirectory
    }
    shadowJar {
        destinationDirectory = rootProject.layout.buildDirectory
    }
    withType<JavaCompile>().configureEach {
        options.encoding = "UTF-8"
    }
    withType<Jar>().configureEach {
        archiveBaseName = "HamsterScript"
        from(rootProject.file("LICENSE"))
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }
    build {
        dependsOn(shadowJar)
    }
}