evaluationDependsOn(":core-common")

dependencies {
    implementation(project(":core-common")) {
        isTransitive = false
    }
    compileOnly("org.spigotmc:spigot-api:1.20.2-R0.1-SNAPSHOT")

    implementation("de.tr7zw:item-nbt-api:2.12.3-SNAPSHOT")
    compileOnly("net.milkbowl.vault:VaultAPI:1.7") {
        isTransitive = false
    }
    compileOnly("org.black_ixx:playerpoints:3.2.6") {
        isTransitive = false
    }
    compileOnly("me.clip:placeholderapi:2.11.5") {
        isTransitive = false
    }

    implementation("net.kyori:adventure-platform-bukkit:4.3.2") {
        exclude(group = "org.jetbrains")
        exclude(group = "com.google.code.gson")
    }
    implementation("net.kyori:adventure-text-minimessage:4.15.0") {
        exclude(module = "adventure-api")
        exclude(group = "org.jetbrains")
    }
    implementation("com.zaxxer:HikariCP:4.0.3") {
        exclude(group = "org.slf4j")
    }
    // https://mvnrepository.com/artifact/io.lettuce/lettuce-core
    implementation("io.lettuce:lettuce-core:6.3.1.RELEASE")
    // https://mvnrepository.com/artifact/org.quartz-scheduler/quartz
    implementation("org.quartz-scheduler:quartz:2.3.2") {
        isTransitive = false
    }
}

tasks {
    processResources {
        filesMatching("plugin.yml") {
            expand(project.properties)
        }
    }
    withType<Jar> {
        archiveBaseName = "HamsterCore-Bukkit"
    }
    shadowJar {
        destinationDirectory = rootProject.buildDir
    }
}