plugins {
    id("java")
    id("maven-publish")
    id("com.github.johnrengelman.shadow") version "8+"
}

group = "cn.hamster3.mc.plugin"
version = "1.3.0"

subprojects {
    apply {
        plugin("java")
        plugin("maven-publish")
        plugin("com.github.johnrengelman.shadow")
    }

    group = rootProject.group
    version = rootProject.version

    repositories {
        maven("https://maven.airgame.net/maven-public")
    }

    dependencies {
        // https://mvnrepository.com/artifact/org.jetbrains/annotations
        compileOnly("org.jetbrains:annotations:24.1.0")
        // https://mvnrepository.com/artifact/org.projectlombok/lombok
        compileOnly("org.projectlombok:lombok:1.18.30")
        annotationProcessor("org.projectlombok:lombok:1.18.30")
    }

    java {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
        withSourcesJar()
    }

    tasks {
        withType<JavaCompile> {
            options.encoding = "UTF-8"
        }
        withType<Jar> {
            from(rootProject.file("LICENSE"))
            duplicatesStrategy = DuplicatesStrategy.EXCLUDE
        }
        jar {
            archiveClassifier = "dev"
        }
        shadowJar {
            archiveClassifier = ""
            relocate("org.quartz", "cn.hamster3.mc.plugin.core.lib.org.quartz")
            relocate("org.terracotta.quartz", "cn.hamster3.mc.plugin.core.lib.org.terracotta.quartz")
            relocate("com.zaxxer.hikari", "cn.hamster3.mc.plugin.core.lib.com.zaxxer.hikari")

            relocate("net.kyori", "cn.hamster3.mc.plugin.core.lib.net.kyori")
            relocate("de.tr7zw.changeme.nbtapi", "cn.hamster3.mc.plugin.core.lib.de.tr7zw.nbtapi")
            relocate("de.tr7zw.annotations", "cn.hamster3.mc.plugin.core.lib.de.tr7zw.nbtapi.annotations")
        }
        build {
            dependsOn(shadowJar)
        }
    }

    publishing {
        publications {
            create<MavenPublication>("mavenJava") {
                from(components["java"])
            }
        }
        repositories {
            maven {
                url = uri("https://maven.airgame.net/public")

                credentials {
                    username = rootProject.properties.getOrDefault("maven_username", "").toString()
                    password = rootProject.properties.getOrDefault("maven_password", "").toString()
                }
            }
        }
    }
}