setArchivesBaseName("HamsterBall-BungeeCord")

evaluationDependsOn(':ball-common')

dependencies {
    apiShade project(":ball-common") transitive false

    //noinspection VulnerableLibrariesLocal
    compileOnly 'net.md-5:bungeecord-api:1.20-R0.1-SNAPSHOT' exclude group: 'io.netty'

    compileOnly "cn.hamster3.mc.plugin:core-bungeecord:${hamster_core_version}"
}

processResources {
    filesMatching("bungee.yml") {
        expand(project.properties)
    }
    duplicatesStrategy(DuplicatesStrategy.EXCLUDE)
}

tasks.compileJava.dependsOn(":ball-common:build")
tasks.register("shadowJar", Jar) {
    dependsOn("jar")
    from([
            tasks.jar.outputs.files.collect {
                it.isDirectory() ? it : zipTree(it)
            },
            configurations.shade.collect {
                it.isDirectory() ? it : zipTree(it)
            },
            configurations.apiShade.collect {
                it.isDirectory() ? it : zipTree(it)
            },
            configurations.implementationShade.collect {
                it.isDirectory() ? it : zipTree(it)
            }
    ])
    destinationDirectory = rootProject.buildDir
}
tasks.build.dependsOn(shadowJar)