@file:Suppress("VulnerableLibrariesLocal")

plugins {
    id("java")
}

group = "cn.hamster3.mc.plugin"
version = "1.4.5"
description = "将 HamsterBall 转换成 HamsterService 兼容的 API"

repositories {
    maven {
        url = uri("https://maven.airgame.net/maven-public/")
    }
}

dependencies {
    // https://mvnrepository.com/artifact/org.jetbrains/annotations
    compileOnly("org.jetbrains:annotations:24.1.0")

    compileOnly("org.spigotmc:spigot-api:1.18.2-R0.1-SNAPSHOT")
    compileOnly("net.md-5:bungeecord-api:1.20-R0.1-SNAPSHOT")

    compileOnly("cn.hamster3.mc.plugin:core-bukkit:+")
    compileOnly("cn.hamster3.mc.plugin:ball-bukkit:+")

    compileOnly("me.clip:placeholderapi:2.11.2")
}

tasks {
    withType<JavaCompile>().configureEach {
        options.encoding = "UTF-8"
    }
    withType<Jar>().configureEach {
        from(rootProject.file("LICENSE"))
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }
    java {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
        withSourcesJar()
    }
    jar {
        archiveBaseName = "HamsterBall-Bridge"
        destinationDirectory = rootProject.layout.buildDirectory
    }
    processResources {
        filesMatching(listOf("plugin.yml", "bungee.yml")) {
            expand(project.properties)
        }
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }
}