//file:noinspection VulnerableLibrariesLocal
plugins {
    id 'java'
    id 'maven-publish'
}

group 'cn.hamster3'
version '2.2.1'

repositories {
    maven {
        url = "https://maven.airgame.net/maven-public/"
    }
}

dependencies {
    compileOnly "org.spigotmc:spigot-api:1.12.2-R0.1-SNAPSHOT"
    // https://mvnrepository.com/artifact/org.jetbrains/annotations
    compileOnly group: 'org.jetbrains', name: 'annotations', version: '22.0.0'
    compileOnly "cn.hamster3:HamsterService-Bukkit:2.8.3-SNAPSHOT"
    compileOnly "cn.hamster3:HamsterAPI:2.4.8-SNAPSHOT"
    compileOnly 'net.milkbowl.vault:VaultAPI:1.7'
    compileOnly "me.clip:placeholderapi:2.10.9"

    compileOnly rootProject.fileTree(dir: './libs', includes: ['*.jar'])
}

processResources {
    filesMatching("plugin.yml") {
        expand "version": project.version
    }
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
    withSourcesJar()
}

jar {
    archivesBaseName = "HamsterCurrency"
    destinationDir(rootProject.buildDir)
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.compilerArgs << "-Xlint:unchecked"
}

publishing {
    publications {
        create("mavenJava", MavenPublication.class) {
            artifactId = "HamsterCurrency"
            artifact jar
            artifact sourcesJar
            //artifact javadocJar
        }
    }

    repositories {
        maven {
            url = 'https://maven.airgame.net/public/'

            credentials {
                username maven_username
                password maven_password
            }
        }
    }
}